Renamed opi_player as rtsp_ai_player

misc/rtsp_ai_player/rtsp_ai_player.pro

@@ -0,0 +1,39 @@
+QT += core network
+QT -= gui
+CONFIG += c++11 link_pkgconfig concurrent console
+PKGCONFIG += opencv4
+MOC_DIR = moc
+OBJECTS_DIR = obj
+
+SOURCES = $$PWD/*.cpp $$PWD/../../misc/camera/a8_remote/remoteControl.cpp
+HEADERS = $$PWD/*.h
+INCLUDEPATH += $$PWD/../../misc/camera/a8_remote
+
+opi5 {
+    message("OPI5 build")
+    PKGCONFIG += opencv4 librga stb libturbojpeg
+    INCLUDEPATH += /usr/include/rga
+    QMAKE_CXXFLAGS += -DOPI5_BUILD
+    LIBS += /usr/local/lib/librknnrt.so
+    SOURCES += $$PWD/src-opi5/*.c $$PWD/src-opi5/*.cpp $$PWD/src-opi5/*.cc
+    HEADERS += $$PWD/src-opi5/*.h
+} else:opencv {
+    message("OpenCV build")
+    message("You must use YOLOv8 ONNX files. Azaion model does not work!")
+    message("OpenCV must be version 4.10.0 installed to /usr/local/")
+    QMAKE_CXXFLAGS += -DOPENCV_BUILD
+    QMAKE_LFLAGS += -Wl,-rpath,/usr/local/lib
+    SOURCES += $$PWD/src-opencv-onnx/*.cpp
+    HEADERS += $$PWD/src-opencv-onnx/*.h
+}
+else {
+    message("ONNX build")
+    message("You must use YOLOv8 ONNX files. Azaion ONNX model also works fine.")
+    QMAKE_CXXFLAGS += -DONNX_BUILD
+    INCLUDEPATH += /opt/onnxruntime-linux-x64-1.18.0/include
+    LIBS += /opt/onnxruntime-linux-x64-1.18.0/lib/libonnxruntime.so.1.18.0
+    QMAKE_LFLAGS += -Wl,-rpath,/opt/onnxruntime-linux-x64-1.18.0/lib
+    QMAKE_LFLAGS += -Wl,-rpath,/usr/local/lib
+    SOURCES += $$PWD/src-onnx-runtime/*.cpp
+    HEADERS += $$PWD/src-onnx-runtime/*.h
+}