QT += core
CONFIG += c++11 link_pkgconfig concurrent
PKGCONFIG += opencv4

SOURCES += main.cpp \
    aiengine.cpp \
    aiengineinference.cpp \
    aiengineinferenceonnx.cpp \
    aienginertsplistener.cpp

opi5 {
    message("OPI5 build")
    PKGCONFIG += opencv4 librga stb libturbojpeg
    INCLUDEPATH += /usr/include/rga # not correct in pkg-config file
    QMAKE_CXXFLAGS += -DOPI5_BUILD
    LIBS += /usr/local/lib/librknnrt.so
    OBJECTS_DIR = objs-opi5
    SOURCES += \
        ./opi5/image_drawing.c \
        ./opi5/file_utils.c \
        ./opi5/postprocess.cc \
        ./opi5/image_utils.c \
        ./opi5/yolov8.cc
}
else {
    message("PC build")
    message("You must use YOLOv10 ONNX files")
    SOURCES += pc/inference.cpp
    QMAKE_CXXFLAGS += -DPC_BUILD
    INCLUDEPATH += /opt/onnxruntime-linux-x64-1.18.0/include
    LIBS += /opt/onnxruntime-linux-x64-1.18.0/lib/libonnxruntime.so.1.18.0
    OBJECTS_DIR = objs-pc
    QMAKE_LFLAGS += -Wl,-rpath,/opt/onnxruntime-linux-x64-1.18.0/lib
}

HEADERS += \
    aiengine.h \
    aiengineinference.h \
    aiengineinferenceonnx.h \
    aienginertsplistener.h \
    config.h